DEBUG
IDENT DEBUG DEBUG 1
TITLE DEBUGGING PACKAGE DEBUG 2
PAGELIM MICRO 1,,*200* DEBUG 3
TITLE SNAPSHOT DUMP PROGRAM DEBUG 4
* TIMING INFORMATION: 10 MILLISECONDS PER DUMP DEBUG 5
ENTRY SNAP DEBUG 6
OCTBCD MACRO XI DEBUG 7
LOCAL LOOP,DONE DEBUG 8
BX1 XI DEBUG 9
SX6 B0 DEBUG 10
SX7 B0 DEBUG 11
SB2 10 DEBUG 12
MX0 57 DEBUG 13
LOOP LX1 3 DEBUG 14
SB2 B2-B1 DEBUG 15
BX2 -X0*X1 DEBUG 16
LX7 6 DEBUG 17
SX2 X2+1R0 DEBUG 18
BX7 X7+X2 DEBUG 19
NZ B2,LOOP DEBUG 20
NZ X6,DONE DEBUG 21
BX6 X7 DEBUG 22
SB2 10 DEBUG 23
SX7 B0 DEBUG 24
EQ LOOP DEBUG 25
DONE BSS 0 DEBUG 26
ENDM DEBUG 27
TITLE REGISTER DUMP SECTION DEBUG 28
SNAPRET SA1 INP DEBUG 29
SA2 OUTP DEBUG 30
SA3 FIRSTP DEBUG 31
SA4 LIMITP DEBUG 32
SA1 X1 DEBUG 33
SA2 X2 DEBUG 34
SA3 X3 DEBUG 35
SA4 X4 DEBUG 36
IX5 X1-X2 AMMOUNT IN BUFFER DEBUG 37
IX0 X4-X3 BUFFER SIZE DEBUG 38
+ PL X5,*+1 DEBUG 39
IX5 X0-X5 COMPENSATE FOR WRAP ROUND DEBUG 40
+ AX0 1 DEBUG 41
IX5 X5-X0 CHECK IF OVER HALF FILLED DEBUG 42
NG X5,SNAPQ DEBUG 43
SA1 STATUSP DEBUG 44
SA1 X1 DEBUG 45
LX1 59 DEBUG 46
PL X1,SNAPQ DEBUG 47
SA2 FILENAM DEBUG 48
SX6 14B WRITE OPCODE DEBUG 49
BX6 X2+X6 DEBUG 50
SA6 A1 DEBUG 51
SA2 WRITE+1 DEBUG 52
BX6 X2 DEBUG 53
+ SA1 B1 DEBUG 54
NZ X1,* DEBUG 55
SA6 A1 DEBUG 56
+ SA1 1 WAIT FOR RA+1 TO CLEAR DEBUG 57
NZ X1,* DEBUG 58
SNAPQ RJ RESTORE DEBUG 59
SNAP BSSZ 1 DEBUG 60
RJ SAVEREG DEBUG 61
* FIND OUTPUT FILE DEBUG 62
RJ GETFET DEBUG 63
SA1 REGI DEBUG 64
BX6 X1 DEBUG 65
SA6 SNAPQ DEBUG 66
SNAPY SA1 SNAP DEBUG 67
LX1 30 DEBUG 68
SB3 B0 REGISTER NUMBER DEBUG 69
SB4 B0 OUTPUT WORD DEBUG 70
SA2 X1-1 GET REQUEST OWRD DEBUG 71
SB1 B2 SET B1 TO 1 DEBUG 72
MX0 36 DEBUG 73
BX4 -X0*X2 GET BITS DEBUG 74
MX0 6 DEBUG 75
LX0 30 DEBUG 76
BX6 X0*X2 DEBUG 77
AX6 24 DEBUG 78
SA6 NUMBLK DEBUG 79
SX6 B0 DEBUG 80
SA6 LINE+1 DEBUG 81
DUP 12,1 DEBUG 82
SA6 A6+B1 DEBUG 83
ZR X4,SNAPB SENSE NO INPUT DEBUG 84
LX4 36 POSITON FIRST BIT DEBUG 85
SNAPL PL X4,SNAPI DEBUG 86
SA1 PR+B3 GET REGISTER TO BE CONVERTED DEBUG 87
OCTBCD X1 DEBUG 88
SA2 STBL+B3 GET TABLE DEBUG 89
SX5 B0 DEBUG 90
MX3 6 DEBUG 91
SHIFTPL SX2 X2-10 DEBUG 92
NG X2,SHIFTPLA DEBUG 93
SA1 =10H DEBUG 94
BX5 X6 DEBUG 95
BX6 X7 DEBUG 96
BX7 X1 DEBUG 97
EQ SHIFTPL DEBUG 98
SHIFTPLA SB2 X2+10 DEBUG 99
ZR B2,SHIFTD DEBUG 100
SHIFTL SX1 1R DEBUG 101
BX2 X3*X7 DEBUG 102
BX7 -X3*X7 DEBUG 103
LX7 6 DEBUG 104
IX7 X7+X1 DEBUG 105
LX2 6 DEBUG 106
BX1 X3*X6 DEBUG 107
BX6 -X3*X6 DEBUG 108
LX6 6 DEBUG 109
IX6 X6+X2 DEBUG 110
LX1 6 DEBUG 111
BX5 -X3*X5 DEBUG 112
LX5 6 DEBUG 113
IX5 X5+X1 DEBUG 114
SB2 B2-B1 DEBUG 115
NZ B2,SHIFTL DEBUG 116
SHIFTD SA1 STBL+B3 GET TABLE DEBUG 117
MX2 18 DEBUG 118
BX5 -X2*X5 DEBUG 119
BX3 X2*X1 DEBUG 120
BX5 X5+X3 DEBUG 121
SB2 16 DEBUG 122
LT B2,B3,STB DEBUG 123
SB2 12 DEBUG 124
NE B4,B2,OKA DEBUG 125
SB4 B0 DEBUG 126
RJ PRINTL DEBUG 127
OKA BX6 X5 DEBUG 128
SA6 1+LINE+B4 DEBUG 129
SB4 B4+B1 DEBUG 130
EQ SNAPI DEBUG 131
STB SB2 10 DEBUG 132
LT B4,B2,OKB DEBUG 133
SB4 B0 DEBUG 134
RJ PRINTL DEBUG 135
OKB SA7 1+LINE+2+B4 DEBUG 136
SA6 1+LINE+1+B4 DEBUG 137
BX7 X5 DEBUG 138
SA7 1+LINE+B4 DEBUG 139
SB4 B4+3 DEBUG 140
SNAPI SB3 B3+B1 DEBUG 141
LX4 1 DEBUG 142
SB2 25 DEBUG 143
NE B3,B1,CONC DEBUG 144
SB3 B3+B1 DEBUG 145
CONC NE B3,B2,SNAPL DEBUG 146
RJ PRINTL PRINT LAST LINE DEBUG 147
EQ SNAPB DEBUG 148
GETFET DATA 0 DEBUG 149
SA1 FILENAM+2 DEBUG 150
ZR X1,CREFET DEBUG 151
MX2 42 DEBUG 152
SA5 FILENAM DEBUG 153
SA1 2 DEBUG 154
GETFETL SX3 X1 DEBUG 155
ZR X3,CREFET NO OUTPUT FILE FOUND DEBUG 156
BX3 X2*X1 DEBUG 157
BX3 X3-X5 DEBUG 158
ZR X3,FOUND DEBUG 159
GETFETX SA1 A1+1 DEBUG 160
SX3 A1-62 DEBUG 161
NG X3,GETFETL DEBUG 162
CREFET SX6 IN DEBUG 163
SX7 OUT DEBUG 164
SA6 INP DEBUG 165
SA7 OUTP DEBUG 166
SX6 FIRST DEBUG 167
SX7 LIMIT DEBUG 168
SA6 FIRSTP DEBUG 169
SA7 LIMITP DEBUG 170
SX6 STATUS DEBUG 171
SSTATUS SA6 STATUSP DEBUG 172
SA1 WRITE DEBUG 173
MX2 42 DEBUG 174
BX1 X2*X1 DEBUG 175
BX7 X6+X1 DEBUG 176
SA7 A1 DEBUG 177
SA1 A1+1 DEBUG 178
BX1 X2*X1 DEBUG 179
BX7 X1+X6 DEBUG 180
SA7 A1 DEBUG 181
EQ GETFET DEBUG 182
FOUND SA3 X1 DEBUG 183
BX3 X3*X2 DEBUG 184
BX3 X3-X5 DEBUG 185
NZ X3,GETFETX DEBUG 186
SX6 X1+1 DEBUG 187
SX7 X1+2 DEBUG 188
SA6 FIRSTP DEBUG 189
SA7 INP DEBUG 190
SX6 X1+3 DEBUG 191
SX7 X1+4 DEBUG 192
SA6 OUTP DEBUG 193
SA7 LIMITP DEBUG 194
SX6 X1 DEBUG 195
SA1 X6+1 GET FIRST DEBUG 196
SA2 X6+4 GET LIMIT DEBUG 197
IX1 X2-X1 DEBUG 198
SX1 X1-78 DEBUG 199
PL X1,SSTATUS DEBUG 200
+ SA1 1 DEBUG 201
NZ X1,* DEBUG 202
SA2 FILENAM DEBUG 203
SA3 TOOSMALL DEBUG 204
BX6 X2 DEBUG 205
LX7 X3 DEBUG 206
SA6 FNAME DEBUG 207
SA7 A1 DEBUG 208
SX6 3RABT DEBUG 209
LX6 42 DEBUG 210
+ SA1 1 DEBUG 211
NZ X1,* DEBUG 212
SA6 A1 DEBUG 213
VFD 45/0 DEBUG 214
TOOSMALL VFD 18/3HMSG,2/1,40/*+1 DEBUG 215
VFD 30/*+1,30/0 DEBUG 216
DIS 5,DEBUG EXTERNAL BUFFER LT 78 WORDS. FILE = DEBUG 217
FNAME DATA 0 DEBUG 218
TITLE PRINT ONE LINE SUBROUTINE DEBUG 219
PRINTL BSSZ 1 DEBUG 220
SA7 TEMP MAY USE X0,X1,X2,X3,B2,B5,B6,B7 DEBUG 221
SA6 A7+B1 DEBUG 222
PRINTLA SA1 INP AND NOW X6 AND X7 DEBUG 223
SA2 OUTP DEBUG 224
SA3 FIRSTP DEBUG 225
SA1 X1 DEBUG 226
SA2 X2 DEBUG 227
SA3 X3 DEBUG 228
SB5 X1 B5=IN DEBUG 229
SB6 X2 B6=OUT DEBUG 230
SA1 LIMITP DEBUG 231
SA1 X1 DEBUG 232
SB2 X3 B2=FIRST DEBUG 233
SB7 X1 B7=LIMIT DEBUG 234
SX0 B0 X0=LINE WORD OUNT DEBUG 235
SX1 B5-B6 SPACE IN BUFFER DEBUG 236
+ NG X1,*+1 CHECK IF NOT WRAPPED AROUND DEBUG 237
SX2 B7-B2 DEBUG 238
IX1 X1-X2 COMPENSATE FOR NO WRAP AROUND DEBUG 239
SX2 X1+15 CHECK IF SAPACE REMAINING IS GT 15 DEBUG 240
SX7 B0 DEBUG 241
NG X2,GO DEBUG 242
SA1 STATUSP CHECK IF FILE IS NOW BUSY DEBUG 243
SA1 X1 DEBUG 244
LX1 59 IF SO JUST WAIT TIL THERE IS ROOM DEBUG 245
PL X1,WAIT DEBUG 246
SA1 WRITE GET CIO REQUEST DEBUG 247
SA2 FILENAM GET FILE NAME DEBUG 248
SX7 14B WRITE OP CODE DEBUG 249
BX6 X1 DEBUG 250
BX7 X7+X2 DEBUG 251
SA1 STATUSP DEBUG 252
SA7 X1 NEW OP CODE IN FET DEBUG 253
+ SA1 B1 WAIT FOR RA+1 DEBUG 254
NZ X1,* DEBUG 255
SA6 A1 DEBUG 256
WAITR SA1 1 WAIT FOR RA+1 TO CLEAR DEBUG 257
NZ X1,* DEBUG 258
EQ PRINTLA DEBUG 259
WAIT SA1 1 DEBUG 260
NZ X1,* DEBUG 261
SA2 RECALL GO INTO PERIODIC RECALL DEBUG 262
BX6 X2 DEBUG 263
SA6 A1 DEBUG 264
EQ WAITR DEBUG 265
GO SA1 LINE+X0 GET WORD TO BE MOVED DEBUG 266
BX6 X1 DEBUG 267
SA7 A1 ZERO OUT LINE DEBUG 268
SA6 B5 DEBUG 269
+ SB5 B5+B1 INCREMENT IN DEBUG 270
NE B5,B7,*+1 CHECK IF AT LIMIT OF THE BUFFER DEBUG 271
SB5 B2 RESET IN TO FIRST DEBUG 272
SX0 X0+B1 INCREMENT WORD COUNT DEBUG 273
NZ X1,GO CHECK IF MOVED A ZERO WORD INTO BUFFER DEBUG 274
DONE SX6 B5 DEBUG 275
SA1 =10H DEBUG 276
SA2 INP DEBUG 277
SA6 X2 UPDATEIN DEBUG 278
BX7 X1 DEBUG 279
SA1 TEMP DEBUG 280
SA7 LINE REBLANK FIRST WORD OF LINE DEBUG 281
SA2 A1+B1 DEBUG 282
SA3 LINECNT DEBUG 283
SX6 X3+B1 DEBUG 284
SA6 A3 DEBUG 285
SX7 X3 DEBUG 286
SA3 FILENAM+1 DEBUG 287
IX3 X7-X3 CHECK FOR MORE THAN 100 PAGES SNAP OUT DEBUG 288
PL X3,ABORT DEBUG 289
BX7 X1 RESTORE X6 AND X7 DEBUG 290
LX6 X2 DEBUG 291
EQ PRINTL DEBUG 292
ABORT SA1 1 DEBUG 293
NZ X1,* DEBUG 294
SA2 MSG DEBUG 295
BX6 X2 DEBUG 296
SA6 A1 DEBUG 297
SENDABT SA1 STATUSP DEBUG 298
SA2 X1 DEBUG 299
LX2 59 DEBUG 300
NG X2,READOKOK DEBUG 301
SX6 3RRCL DEBUG 302
LX6 2 DEBUG 303
SX7 1 DEBUG 304
BX6 X6+X7 DEBUG 305
LX6 40 DEBUG 306
BX6 X6+X1 DEBUG 307
+ SA2 1 DEBUG 308
NZ X2,* DEBUG 309
SA6 A2 DEBUG 310
+ SA2 1 DEBUG 311
NZ X2,* DEBUG 312
READOKOK BSS 0 DEBUG 313
SA2 WRITE CIO REQ DEBUG 314
SA3 FILENAM DEBUG 315
SX6 36B DEBUG 316
BX7 X2 DEBUG 317
BX6 X6+X3 DEBUG 318
SA6 X1 DEBUG 319
+ SA1 1 DEBUG 320
NZ X1,* DEBUG 321
SA7 A1 DEBUG 322
SX6 3RABT DEBUG 323
LX6 42 DEBUG 324
+ SA1 1 DEBUG 325
NZ X1,* DEBUG 326
SA6 A1 DEBUG 327
EQ * DEBUG 328
MSG VFD 18/3HMSG,2/1,40/*+1 DEBUG 329
VFD 30/*+1,30/0 DEBUG 330
DIS ,(DEBUG LINE LIMIT EXCEEDED( DEBUG 331
LINECNT DATA 0 DEBUG 332
TITLE SHIFT TABLE DEBUG 333
STBL VFD 18/3LP =,42/21 DEBUG 334
BSSZ 1 DEBUG 335
VFD 18/3LB1=,42/21 DEBUG 336
VFD 18/3LB2=,42/21 DEBUG 337
VFD 18/3LB3=,42/21 DEBUG 338
VFD 18/3LB4=,42/21 DEBUG 339
VFD 18/3LB5=,42/21 DEBUG 340
VFD 18/3LB6=,42/21 DEBUG 341
VFD 18/3LB7=,42/21 DEBUG 342
VFD 18/3LA0=,42/21 DEBUG 343
VFD 18/3LA1=,42/21 DEBUG 344
VFD 18/3LA2=,42/21 DEBUG 345
VFD 18/3LA3=,42/21 DEBUG 346
VFD 18/3LA4=,42/21 DEBUG 347
VFD 18/3LA5=,42/21 DEBUG 348
VFD 18/3LA6=,42/21 DEBUG 349
VFD 18/3LA7=,42/21 DEBUG 350
VFD 18/3LX0=,42/7 DEBUG 351
VFD 18/3LX1=,42/7 DEBUG 352
VFD 18/3LX2=,42/7 DEBUG 353
VFD 18/3LX3=,42/7 DEBUG 354
VFD 18/3LX4=,42/7 DEBUG 355
VFD 18/3LX5=,42/7 DEBUG 356
VFD 18/3LX6=,42/7 DEBUG 357
VFD 18/3LX7=,42/7 DEBUG 358
TITLE CORE DUMP SECTION DEBUG 359
SNAPB SA0 B0 SET SWITCH TO FIRST TIME THROUGH DEBUG 360
SA1 NUMBLK DEBUG 361
SA2 SNAP DEBUG 362
SX3 X1 DEBUG 363
LX3 30 DEBUG 364
IX6 X2+X3 INCREMENT RETURN DEBUG 365
SA6 A2 DEBUG 366
SB3 X1 B3=NUMBER OF BLOCKS DEBUG 367
LX2 30 DEBUG 368
SB4 X2 B4=ADDRESS OF NEXT REQUEST DEBUG 369
SNAPLT ZR B3,SNAPRET DEBUG 370
SA4 B4 GET REQUEST DEBUG 371
BX5 X4 X4=FIRST OWRD ADDRESS DEBUG 372
AX5 30 X5=LAST OWRD ADDRESS DEBUG 373
MX0 58 DEBUG 374
BX4 X0*X4 ROUND DOWN TO MULTIPLE OF 4 DEBUG 375
RJ PRINTL PRINT BLANK LINE DEBUG 376
OCTBCD X4 DEBUG 377
SA7 FIRSTL DEBUG 378
OCTBCD X5 DEBUG 379
SA1 FIRSTL DEBUG 380
MX0 24 DEBUG 381
SA2 =4L TO DEBUG 382
SA3 =10HDUMP FROM DEBUG 383
BX6 X3 DEBUG 384
SA6 LINE+1 DEBUG 385
BX6 -X0*X1 DEBUG 386
BX6 X6+X2 DEBUG 387
LX6 18 DEBUG 388
SA2 =4L DEBUG 389
SA6 A6+B1 DEBUG 390
BX7 -X0*X7 DEBUG 391
BX7 X2+X7 DEBUG 392
LX7 18 DEBUG 393
SA7 A6+B1 DEBUG 394
SX6 B0 DEBUG 395
SA6 A7+B1 DEBUG 396
RJ PRINTL DEBUG 397
RJ PRINTL PRINT BLANK LINE DEBUG 398
SA0 B0 SET SWITCH TO FIRST TIME TRU DEBUG 399
SNAPLD OCTBCD X4 CONVERT THE ADDRESS OF THE LINE DEBUG 400
SA1 =4L DEBUG 401
MX0 24 DEBUG 402
BX7 -X0*X7 DEBUG 403
BX7 X7+X1 INSERT LEADING BLANKS DEBUG 404
LX7 24 LEFT ADJUST BLANK FILL DEBUG 405
SA7 LINE+1 STORE ADDRESS DEBUG 406
SX3 A0 CHECK SWITCH DEBUG 407
ZR X3,NOCHECK DEBUG 408
SA1 X4 CHECK THIS LINE AGAINST THE LAST DEBUG 409
SA2 LAST DEBUG 410
SB2 4 DEBUG 411
CHECKL BX2 X2-X1 CHECK IF THIS WORD SAME AS LAST CORR. WDEBUG 412
NZ X2,NOCHECK DEBUG 413
SB2 B2-B1 DEBUG 414
SA1 A1+B1 DEBUG 415
SA2 A2+B1 DEBUG 416
NZ B2,CHECKL DEBUG 417
SA7 LASTADR SAVE ADDRESS OF START OF LINE DEBUG 418
SA0 B1+B1 THIS LINE IS THE SAME AS LAST DEBUG 419
SX4 X4+4 DEBUG 420
EQ CHECKE DEBUG 421
NOCHECK SX3 X3-2 CHECK IF THIS FINISHES A SEQUENCE OF EQDEBUG 422
NG X3,DUMPIT LOCATIONS DEBUG 423
SA7 SAVEREG SAVE ADDRESS OF LINE DEBUG 424
NOCHECKB SA1 MESSG YES IT DOES DEBUG 425
SA2 A1+B1 MOVE MESSAGE TO BUFFER DEBUG 426
BX6 X1 DEBUG 427
LX7 X2 DEBUG 428
SA6 LINE+1 DEBUG 429
SA7 A6+B1 DEBUG 430
SA1 LASTADR DEBUG 431
SA2 MESSG+3 DEBUG 432
BX6 X1 DEBUG 433
LX7 X2 DEBUG 434
SA6 A7+B1 DEBUG 435
SA7 A6+B1 DEBUG 436
DUP 4,6 FINISH MESSAGE DEBUG 437
SA1 A2+B1 DEBUG 438
SA2 A1+B1 DEBUG 439
BX6 X1 DEBUG 440
LX7 X2 DEBUG 441
SA6 A7+B1 DEBUG 442
SA7 A6+B1 DEBUG 443
RJ PRINTL DEBUG 444
SX1 A0-3 CHECK IF CALLED FROM THE EXIT ROUTINE DEBUG 445
ZR X1,SNAPX DEBUG 446
SA1 SAVEREG DEBUG 447
BX6 X1 DEBUG 448
SA6 LINE+1 DEBUG 449
DUMPIT SA0 B1 DEBUG 450
SB7 4 WORD COUNT DEBUG 451
SB6 B0 LINE LOCATION DEBUG 452
SB5 B0 LAST ADDRESS DEBUG 453
DUMPITL SA1 X4 GET WORD TO BE DUMPED DEBUG 454
SX4 X4+B1 INCREMENT WORD LOCATION DEBUG 455
BX6 X1 DEBUG 456
SA6 LAST+B5 SAVE IN LAST FOR COMPARISON NEXT LINE DEBUG 457
OCTBCD X1 DEBUG 458
SA6 LINE+2+B6 STORE OUTPUT IN LINE DEBUG 459
SA7 A6+B1 DEBUG 460
SA1 =10H DEBUG 461
SB6 B6+3 DEBUG 462
BX6 X1 DEBUG 463
SB7 B7-B1 DEBUG 464
ZR B7,DUMPITY DEBUG 465
SA6 A7+B1 DEBUG 466
SB5 B5+B1 DEBUG 467
EQ DUMPITL DEBUG 468
DUMPITY RJ PRINTL PRINT OUT THE LINE OF INFORMATION DEBUG 469
CHECKE IX1 X5-X4 CHECK IF AREA HAS BEEN DUMPED YET DEBUG 470
PL X1,SNAPLD NOT TYT DEBUG 471
SX1 A0 DEBUG 472
SX1 X1-2 CHECK IF DUMPLICATE IN PROCESS DEBUG 473
NG X1,SNAPX NO DEBUG 474
SA0 3 YES GO BACK PROCESS DUP LINE DEBUG 475
EQ NOCHECKB DEBUG 476
SNAPX SB3 B3-B1 GET NEXT BLOCK DEBUG 477
SB4 B4+B1 INCREMENT REQUEST ADDRESS DEBUG 478
EQ SNAPLT LOOP BACK DEBUG 479
TITLE REGISTER SAVING ROUTINE DEBUG 480
SAVEREG DATA 0 DEBUG 481
DUP 18,3 DEBUG 482
PL B1,*+2 DEBUG 483
+ RJ * DEBUG 484
SB1 B1+B1 DEBUG 485
SB1 A6-B0 SAVE A6 DEBUG 486
SA6 XR6 STORE X6 DEBUG 487
SX6 A7-B0 SAVE A7 DEBUG 488
SA6 AR7 STORE A7 DEBUG 489
SA7 XR7 STORE X7 DEBUG 490
SX6 B2-B0 DEBUG 491
SX7 B3-B0 DEBUG 492
SB2 1 DEBUG 493
SA6 BR2 DEBUG 494
SA7 A6+B2 DEBUG 495
SX6 B4-B0 DEBUG 496
SX7 B5-B0 DEBUG 497
SA6 A7+B2 DEBUG 498
SA7 A6+B2 DEBUG 499
SX6 B6-B0 DEBUG 500
SX7 B7-B0 DEBUG 501
SA6 A7+B2 DEBUG 502
SA7 A6+B2 DEBUG 503
SX6 A0-B0 DEBUG 504
SX7 A1-B0 DEBUG 505
SA6 A7+B2 DEBUG 506
SA7 A6+B2 DEBUG 507
SX6 A2-B0 DEBUG 508
SX7 A3-B0 DEBUG 509
SA6 A7+B2 DEBUG 510
SA7 A6+B2 DEBUG 511
SX6 A4-B0 DEBUG 512
SX7 A5-B0 DEBUG 513
SA6 A7+B2 DEBUG 514
SA7 A6+B2 DEBUG 515
SX6 B1-B0 DEBUG 516
BX7 X0 DEBUG 517
SA6 A7+B2 DEBUG 518
SA7 XR0 DEBUG 519
BX6 X1 DEBUG 520
LX7 X2 DEBUG 521
SA6 A7+B2 DEBUG 522
SA7 A6+B2 DEBUG 523
BX6 X3 DEBUG 524
LX7 X4 DEBUG 525
SA6 A7+B2 DEBUG 526
SA7 A6+B2 DEBUG 527
BX6 X5 DEBUG 528
SA6 A7+B2 DEBUG 529
SB4 B2+B2 DEBUG 530
MX0 6 DEBUG 531
SX7 B0 DEBUG 532
SA1 SAVEREG DEBUG 533
SB3 18 DEBUG 534
SA3 =1LA DEBUG 535
LOOPR SA1 A1+B4 DEBUG 536
SB3 B3-B2 DEBUG 537
IX7 X7+X7 DEBUG 538
BX6 -X0*X1 DEBUG 539
AX1 56 DEBUG 540
BX6 X6+X3 DEBUG 541
IX7 X7+X1 DEBUG 542
LX1 30 DEBUG 543
IX6 X6-X1 DEBUG 544
SA6 A1 DEBUG 545
NZ B3,LOOPR DEBUG 546
LX7 42 SIGN EXTEND DEBUG 547
AX7 42 DEBUG 548
SA7 BR1 DEBUG 549
SA1 SAVEREG DEBUG 550
AX1 30 DEBUG 551
SA1 X1-2 DEBUG 552
AX1 30 DEBUG 553
SX6 X1-1 DEBUG 554
SA6 PR DEBUG 555
EQ SAVEREG DEBUG 556
TITLE REGISTER RESTORE ROUTINE DEBUG 557
RESTORE DATA 0 DEBUG 558
SB1 1 DEBUG 559
MX0 42 DEBUG 560
BX1 -X0 DEBUG 561
SB4 6 DEBUG 562
SB7 X1-0 DEBUG 563
LOOP SA1 RB1+B4 GET RESTORE SKELETON DEBUG 564
SA2 BR1+B4 GET B REGISTER CONTENTS DEBUG 565
BX6 X0*X1 DEBUG 566
BX2 -X0*X2 DEBUG 567
BX6 X2+X6 DEBUG 568
SA6 A1 DEBUG 569
SB4 B4-B1 DEBUG 570
PL B4,LOOP DEBUG 571
SA1 XR1 DEBUG 572
UX1 X1,B2 DEBUG 573
LX1 11 DEBUG 574
UX1 X1,B3 DEBUG 575
LX1 11 DEBUG 576
UX1 X1,B4 DEBUG 577
LX1 11 DEBUG 578
UX1 X1,B5 DEBUG 579
AX1 33 DEBUG 580
SB6 X1 DEBUG 581
SA1 AR6 DEBUG 582
SA2 AR7 DEBUG 583
SA3 XR6 DEBUG 584
SA4 XR7 DEBUG 585
SA1 X1 DEBUG 586
SA2 X2 DEBUG 587
SA5 AR0 DEBUG 588
BX6 X1 DEBUG 589
LX7 X2 DEBUG 590
SA0 X5-0 DEBUG 591
SA6 A1-B0 DEBUG 592
SA7 A2-B0 DEBUG 593
SA5 XR0 DEBUG 594
BX6 X3 DEBUG 595
LX7 X4 DEBUG 596
SA1 XR4 DEBUG 597
SA4 AR4 DEBUG 598
BX0 X5 DEBUG 599
SA2 XR5 DEBUG 600
SA5 AR5 DEBUG 601
SA4 X4-0 DEBUG 602
SA3 AR3 DEBUG 603
SA5 X5-0 DEBUG 604
BX4 X1 DEBUG 605
SA3 X3-0 DEBUG 606
SA1 XR3 DEBUG 607
LX5 X2 DEBUG 608
SA2 AR2 DEBUG 609
BX3 X1 DEBUG 610
SA1 XR2 DEBUG 611
SA2 X2-0 DEBUG 612
BX2 X1 DEBUG 613
SA1 AR1 DEBUG 614
SA1 X1-0 DEBUG 615
SX1 B6 DEBUG 616
LX1 33 DEBUG 617
PX1 X1,B5 DEBUG 618
AX1 11 DEBUG 619
PX1 X1,B4 DEBUG 620
AX1 11 DEBUG 621
PX1 X1,B3 DEBUG 622
AX1 11 DEBUG 623
PX1 X1,B2 DEBUG 624
RB1 NO DEBUG 625
NO DEBUG 626
SB1 0+B7 DEBUG 627
NO DEBUG 628
NO DEBUG 629
SB2 0+B7 DEBUG 630
NO DEBUG 631
NO DEBUG 632
SB3 0+B7 DEBUG 633
NO DEBUG 634
NO DEBUG 635
SB4 0+B7 DEBUG 636
NO DEBUG 637
NO DEBUG 638
SB5 0+B7 DEBUG 639
NO DEBUG 640
NO DEBUG 641
SB6 0+B7 DEBUG 642
NO DEBUG 643
NO DEBUG 644
SB7 0+B7 DEBUG 645
EQ RESTORE DEBUG 646
TITLE TEMPORARIES DEBUG 647
ENTRY FILENAM DEBUG 648
LINE DIS 1, DEBUG 649
BSSZ 12 DEBUG 650
BSSZ 1 DEBUG 651
FILENAM DATA 6LOUTPUT DEBUG 652
VFD 60/56*'PAGELIM' DEBUG 653
DATA 1 DEBUG 654
STATUS DATA 1 DEBUG 655
FIRST VFD 60/BUFF DEBUG 656
IN VFD 60/BUFF DEBUG 657
OUT VFD 60/BUFF DEBUG 658
LIMIT VFD 60/BUFF+SIZE DEBUG 659
* MINIMUM BUFFER SIZE IS 80 WORDS. DEBUG 660
SIZE EQU 100 DEBUG 661
STATUSP DEBUG 662
FIRSTP DEBUG 663
INP DEBUG 664
OUTP DEBUG 665
LIMITP DEBUG 666
BUFF BSSZ SIZE DEBUG 667
WRITE VFD 18/3LCIO,2/1,40/STATUS DEBUG 668
VFD 18/3LCIO,42/STATUS DEBUG 669
RECALL DATA 3LRCL DEBUG 670
NUMBLK BSSZ 1 DEBUG 671
LAST BSSZ 4 DEBUG 672
LASTADR BSSZ 1 DEBUG 673
FIRSTL BSSZ 1 DEBUG 674
MESSG DIS 2,LINES THROUGH DEBUG 675
BSSZ 1 DEBUG 676
DIS 5, ARE IDENTICAL WITH THE PREVIOUS LINE DEBUG 677
DIS 5, DEBUG 678
TEMP BSSZ 2 DEBUG 679
TITLE REGISTER AREA DEBUG 680
PR DEBUG 681
BR0 DEBUG 682
BR1 DEBUG 683
BR2 DEBUG 684
BR3 DEBUG 685
BR4 DEBUG 686
BR5 DEBUG 687
BR6 DEBUG 688
BR7 DEBUG 689
AR0 DEBUG 690
AR1 DEBUG 691
AR2 DEBUG 692
AR3 DEBUG 693
AR4 DEBUG 694
AR5 DEBUG 695
AR6 DEBUG 696
AR7 DEBUG 697
XR0 DEBUG 698
XR1 DEBUG 699
XR2 DEBUG 700
XR3 DEBUG 701
XR4 DEBUG 702
XR5 DEBUG 703
XR6 DEBUG 704
XR7 DEBUG 705
TITLE TRACE SECTION DEBUG 706
SNAPONLY IF -DEF,SNAPASSM DEBUG 707
* TRACE PROGRAM DEBUG 708
* WRITTEN 6/1/68 BY KARL MALBRAIN DEBUG 709
* REGISTER USAGE IN THE TRACE SECTION: DEBUG 710
* B1 1 DEBUG 711
* B2 WORK DEBUG 712
* B3 PARCEL COUNTER DEBUG 713
* B4 WORK DEBUG 714
* B5 K OPREG NO. DEBUG 715
* B6 J OPREG NO. DEBUG 716
* B7 I OPREG NO. DEBUG 717
* A0 CURRENT OP CODE DEBUG 718
* X0 CURRENT INSTRUCTION WORD DEBUG 719
* X1 OPERAND 1 DEBUG 720
* X2 OPERAND 2 DEBUG 721
* X3 WORK DEBUG 722
* X4 NEXT 15 BITS OF INSTRUCTION DEBUG 723
* X5 NEXT INSTRUCTION WORD DEBUG 724
* X6 WORK DEBUG 725
* X7 RESULT OPERAND DEBUG 726
SPREAD MACRO DEBUG 727
MX4 1 DEBUG 728
LX4 8 DEBUG 729
AX4 X4,B4 DEBUG 730
ENDM DEBUG 731
EVAL MACRO Q DEBUG 732
IFC EQ,*Q*K*,2 DEBUG 733
'ANS'X SET 0 DEBUG 734
'ANS' SET 0 DEBUG 735
IFC EQ,*Q*A*,2 DEBUG 736
'ANS'X SET 1 DEBUG 737
'ANS' SET AR0 DEBUG 738
IFC EQ,*Q*B*,2 DEBUG 739
'ANS'X SET 2 DEBUG 740
'ANS' SET BR0 DEBUG 741
IFC EQ,*Q*X*,2 DEBUG 742
'ANS'X SET 3 DEBUG 743
'ANS' SET XR0 DEBUG 744
IFC EQ,*Q*N*,2 DEBUG 745
'ANS'X SET 0 NO REGISTER DEBUG 746
'ANS' SET BR0 DEBUG 747
ENDM DEBUG 748
OPCODE MACRO A,Y,Z DEBUG 749
ANS MICRO 1,,*I=* DEBUG 750
EVAL A DEBUG 751
ANS MICRO 1,,*J=* DEBUG 752
EVAL Y DEBUG 753
ANS MICRO 1,,*K=* DEBUG 754
EVAL Z DEBUG 755
M= SET 0 DEBUG 756
IFEQ K=,0,1 DEBUG 757
M= SET 1 DEBUG 758
VFD 1/M=,1/0,2/I=X,2/J=X,2/K=X,22/J=,30/K= DEBUG 759
ENDM DEBUG 760
SUB MACRO DEBUG 761
LOCAL EXIT DEBUG 762
SA1 PR DEBUG 763
SA3 X1+1 GET SNAP CALL DEBUG 764
SA4 CMREFIN DEBUG 765
BX6 X3 DEBUG 766
SA3 CMREFLMT DEBUG 767
SA1 CMREF DEBUG 768
MX7 1 DEBUG 769
LX7 31 DEBUG 770
SA6 X4 DEBUG 771
IX7 X1+X7 DEBUG 772
SX6 X4+B2 DEBUG 773
IX4 X6-X3 DEBUG 774
SA6 A4 DEBUG 775
SA7 A1 DEBUG 776
NZ X4,EXIT DEBUG 777
SA1 CMREFFST DEBUG 778
BX6 X1 DEBUG 779
SA6 A4 DEBUG 780
EXIT BSS 0 DEBUG 781
ENDM DEBUG 782
X MACRO DEBUG 783
SA7 X3+B7 DEBUG 784
EQ TRAP DEBUG 785
ENDM DEBUG 786
TITLE CMREF STOP HANDLING DEBUG 787
CMREF DATA 0 DEBUG 788
RJ SAVEREG DEBUG 789
SUB DEBUG 790
RJ RESTORE DEBUG 791
EQ CMREF DEBUG 792
TITLE TRACER DEBUG 793
TRACE DATA 0 DEBUG 794
RJ SAVEREG DEBUG 795
SB1 B2 DEBUG 796
SB3 60 DEBUG 797
RJ RNI DEBUG 798
TLLOOP RJ GETPARCL GET NEXT PARCEL DEBUG 799
SX6 B0 DEBUG 800
SA6 BR0 DEBUG 801
SX1 X4 DEBUG 802
SX6 1R -1R DEBUG 803
SA6 =SJPCHAR DEBUG 804
AX1 9 DEBUG 805
SA0 X1 SAVE OP CODE DEBUG 806
SA3 OPCODE+A0 PICK UP INFO ON OPCODE DEBUG 807
MX2 57 DEBUG 808
BX6 -X2*X4 GET K DEBUG 809
SA6 =SKFIELD DEBUG 810
SB5 X6 DEBUG 811
AX4 3 DEBUG 812
BX6 -X2*X4 GET J DEBUG 813
SA6 =SJFIELD DEBUG 814
SB6 X6 DEBUG 815
AX4 3 DEBUG 816
BX6 -X2*X4 DEBUG 817
SA6 =SIFIELD DEBUG 818
SB7 X6 GET I DEBUG 819
PL X3,NOK SENSE NO K FIELD DEBUG 820
RJ GETPARCL GET K FIELD DEBUG 821
SX6 B5 DEBUG 822
LX6 57 DEBUG 823
AX6 42 DEBUG 824
BX1 X6+X4 PUT TOGETHER K FIELD DEBUG 825
SB5 X1-0 REGERERATE K IN B5 DEBUG 826
SX6 X1-0 DEBUG 827
SA6 =SKFIELD DEBUG 828
EQ CONT DEBUG 829
NOK SA1 X3+B5 DEBUG 830
CONT AX3 30 DEBUG 831
SA2 X3+B6 GET J OPERAND DEBUG 832
SB4 A0 DEBUG 833
SX3 XR0 DEBUG 834
SB2 AR0 DEBUG 835
JP *+1+B4 CALL PROCESSOR DEBUG 836
EQ PS DEBUG 837
EQ RJ DEBUG 838
EQ JP DEBUG 839
EQ XRT DEBUG 840
SA1 BR0+B7 DEBUG 841
EQ BREQ DEBUG 842
SA1 BR0+B7 DEBUG 843
EQ BRNE DEBUG 844
SA1 BR0+B7 DEBUG 845
EQ BRGE DEBUG 846
SA1 BR0+B7 DEBUG 847
EQ BRLT DEBUG 848
TRAPS BX7 X2 10 DEBUG 849
SA7 X3+B7 DEBUG 850
EQ TRAP DEBUG 851
BX7 X1*X2 DEBUG 852
SA7 X3+B7 DEBUG 853
EQ TRAP DEBUG 854
BX7 X1+X2 DEBUG 855
X DEBUG 856
BX7 X1-X2 13 DEBUG 857
X DEBUG 858
BX7 -X1 14 DEBUG 859
X DEBUG 860
BX7 -X1*X2 15 DEBUG 861
X DEBUG 862
BX7 -X1+X2 16 DEBUG 863
X DEBUG 864
BX7 -X1-X2 17 DEBUG 865
X DEBUG 866
SA1 X3+B7 20 DEBUG 867
EQ LXJK DEBUG 868
SA1 X3+B7 DEBUG 869
EQ AXJK DEBUG 870
SB4 X2 22 DEBUG 871
LX2 X1,B4 DEBUG 872
EQ TRAPS DEBUG 873
SB4 X2 DEBUG 874
AX2 X1,B4 DEBUG 875
EQ TRAPS DEBUG 876
NX7 X1,B4 DEBUG 877
SA7 X3+B7 DEBUG 878
EQ TRAPN DEBUG 879
ZX7 X1,B4 DEBUG 880
SA7 X3+B7 DEBUG 881
EQ TRAPN DEBUG 882
UX7 X1,B4 DEBUG 883
SA7 X3+B7 DEBUG 884
EQ TRAPN DEBUG 885
SB4 X2 DEBUG 886
PX2 X1,B4 DEBUG 887
EQ TRAPS DEBUG 888
FX7 X1+X2 30 DEBUG 889
X DEBUG 890
FX7 X2-X1 DEBUG 891
X DEBUG 892
DX7 X1+X2 32 DEBUG 893
X DEBUG 894
DX7 X2-X1 33 DEBUG 895
X DEBUG 896
RX7 X1+X2 DEBUG 897
X DEBUG 898
RX7 X2-X1 35 DEBUG 899
X DEBUG 900
IX7 X1+X2 36 DEBUG 901
X DEBUG 902
IX7 X2-X1 37 DEBUG 903
X DEBUG 904
FX7 X1*X2 40 DEBUG 905
X DEBUG 906
RX7 X1*X2 41 DEBUG 907
X DEBUG 908
DX7 X1*X2 DEBUG 909
X DEBUG 910
EQ MXJK 43 DEBUG 911
FX7 X2/X1 DEBUG 912
X DEBUG 913
RX7 X2/X1 45 DEBUG 914
X DEBUG 915
ZR B5,TRAP NOP DEBUG 916
EQ PRCSOPT SENSE NON ZERO K FIELD DEBUG 917
CX7 X1 DEBUG 918
SA7 X3+B7 DEBUG 919
EQ TRAP DEBUG 920
DUP 2,3 DEBUG 921
IX7 X1+X2 50 DEBUG 922
SX7 X7 DEBUG 923
EQ TRAPG DEBUG 924
DUP 2,3 DEBUG 925
SB4 X2 DEBUG 926
SX7 X1+B4 DEBUG 927
EQ TRAPG DEBUG 928
IX7 X1+X2 54 DEBUG 929
SX7 X7 DEBUG 930
EQ TRAPG DEBUG 931
IX7 X2-X1 55 DEBUG 932
SX7 X7 DEBUG 933
EQ TRAPG DEBUG 934
IX7 X1+X2 56 DEBUG 935
SX7 X7 DEBUG 936
EQ TRAPG DEBUG 937
IX7 X2-X1 57 DEBUG 938
SX7 X7 DEBUG 939
EQ TRAPG DEBUG 940
DUP 2,2 DEBUG 941
IX7 X1+X2 60 DEBUG 942
EQ TRAPSBX DEBUG 943
DUP 2,2 DEBUG 944
SB4 X2-0 DEBUG 945
EQ TRAPSBA DEBUG 946
DUP 2,4 DEBUG 947
IX7 X1+X2 64 DEBUG 948
EQ TRAPSBX DEBUG 949
IX7 X2-X1 65 DEBUG 950
EQ TRAPSBX DEBUG 951
DUP 2,3 DEBUG 952
IX7 X1+X2 70 DEBUG 953
SX2 X7 DEBUG 954
EQ TRAPS DEBUG 955
DUP 2,3 DEBUG 956
SB4 X2 72 DEBUG 957
SX2 X1+B4 DEBUG 958
EQ TRAPS DEBUG 959
DUP 2,6 DEBUG 960
IX7 X1+X2 74 DEBUG 961
SX2 X7 DEBUG 962
EQ TRAPS DEBUG 963
IX7 X2-X1 DEBUG 964
SX2 X7 DEBUG 965
EQ TRAPS DEBUG 966
TRAPSBX SX7 X7-0 DEBUG 967
EQ TRAPSB DEBUG 968
TRAPSBA SX7 X1+B4 DEBUG 969
TRAPSB SA7 BR0+B7 DEBUG 970
EQ TRAP DEBUG 971
TRAPG SA7 AR0+B7 STORE A REGISTER DEBUG 972
ZR B7,TRAP SENSE A 0 INVOLVED DEBUG 973
RJ CKFL DEBUG 974
SX1 B7-6 DEBUG 975
PL X1,TRAPP DEBUG 976
SA1 X7 DEBUG 977
BX7 X1 MAKE MEMORY REFERENCE DEBUG 978
SA7 XR0+B7 STORE IN THE X REGISTER DEBUG 979
EQ TRAP DEBUG 980
TRAPP SA1 XR0+B7 DEBUG 981
BX6 X1 DEBUG 982
SA6 X7 STORE X REGISTER IN MEMORY DEBUG 983
EQ TRAP DEBUG 984
TRAPN SX7 B4 DEBUG 985
SA7 BR0+B6 DEBUG 986
EQ TRAP DEBUG 987
RJ JP RJJMP+B7 DEBUG 988
RJJMP JP RJACT DEBUG 989
JP ECSR DEBUG 990
JP ECSW DEBUG 991
JP CEJ DEBUG 992
DUP 4,1 DEBUG 993
JP RJACT DEBUG 994
ECSR RJ CHKECS DEBUG 995
RE B5 DEBUG 996
JP TRAPX0 DEBUG 997
EQ ABTWORD DEBUG 998
ECSW RJ CHKECS DEBUG 999
WE B5 DEBUG 1000
JP TRAPX0 DEBUG 1001
EQ ABTWORD DEBUG 1002
CHKECS DATA 0 DEBUG 1003
SA3 ECSFL DEBUG 1004
SX3 303000B TIL MEM WILL RETURN FIELD LENGTH DEBUG 1005
NZ X3,ECSCHK DEBUG 1006
GETECS SA1 1 DEBUG 1007
NZ X1,* DEBUG 1008
SA2 ECSCALL DEBUG 1009
BX6 X2 DEBUG 1010
SA6 A1 DEBUG 1011
+ SA1 1 DEBUG 1012
NZ X1,* DEBUG 1013
SA3 ECSFL DEBUG 1014
ECSCHK SA1 XR0 DEBUG 1015
SA2 AR0 DEBUG 1016
NG X2,ARITHERR DEBUG 1017
MX6 36 DEBUG 1018
BX1 -X6*X1 DEBUG 1019
AX3 30 DEBUG 1020
SX6 B5 DEBUG 1021
IX1 X1+X6 DEBUG 1022
IX7 X2+X6 DEBUG 1023
IX1 X1-X3 DEBUG 1024
PL X1,ARITHERR DEBUG 1025
RJ CKFL DEBUG 1026
SA1 XR0 DEBUG 1027
SA2 AR0 DEBUG 1028
BX6 X0 DEBUG 1029
BX0 X1 DEBUG 1030
SX7 A0 DEBUG 1031
SA0 X2 DEBUG 1032
EQ CHKECS DEBUG 1033
CEJ SA1 =10HCEJ ATTEMP DEBUG 1034
SA2 =10HTED DEBUG 1035
EQ ABORTT DEBUG 1036
RJACT SX7 B5 DEBUG 1037
RJ CKFL DEBUG 1038
SA1 PR DEBUG 1039
SX7 B5+B1 DEBUG 1040
SA7 A1 DEBUG 1041
SX6 X1 DEBUG 1042
MX1 1 DEBUG 1043
LX1 57 DEBUG 1044
LX6 30 DEBUG 1045
BX6 X6+X1 DEBUG 1046
SA6 B5 DEBUG 1047
SX1 SNAP DEBUG 1048
SX7 B5 DEBUG 1049
IX1 X7-X1 DEBUG 1050
ZR X1,SNAPCALL DEBUG 1051
SX1 X7-TRACE DEBUG 1052
ZR X1,TRCECALL DEBUG 1053
SX1 X7-UNTRACE DEBUG 1054
ZR X1,UNTRCALL DEBUG 1055
SX1 X7-CMREF DEBUG 1056
ZR X1,CMREFC DEBUG 1057
EQ ABTWORD DEBUG 1058
JP SA1 BR0+B7 DEBUG 1059
SX7 X1+B5 DEBUG 1060
SA7 PR CHANGE SEQUENCE COUNTER DEBUG 1061
EQ ABTWORD DEBUG 1062
XRT SA1 TSTSKEL DEBUG 1063
SX7 B7 DEBUG 1064
LX7 21 DEBUG 1065
BX7 X7+X1 DEBUG 1066
SA7 XRJ DEBUG 1067
+ NO DEBUG 1068
+ NO DEBUG 1069
XRJ DATA 0 DEBUG 1070
EQ TRAP DEBUG 1071
TSTSKEL NO DEBUG 1072
NO DEBUG 1073
ZR X2,EQ DEBUG 1074
EQ SX7 B5 DEBUG 1075
SA7 PR DEBUG 1076
ABTWORD SB3 60 DEBUG 1077
SA1 PR DEBUG 1078
SX7 X1 DEBUG 1079
RJ CKFL DEBUG 1080
SX6 1R -1R* DEBUG 1081
SA6 JPCHAR DEBUG 1082
SA5 X7 DEBUG 1083
SA7 =SWR2 DEBUG 1084
EQ TRAP DEBUG 1085
BREQ IX7 X1-X2 DEBUG 1086
SX7 X7 DEBUG 1087
ZR X7,EQ DEBUG 1088
EQ TRAP DEBUG 1089
BRNE IX7 X1-X2 DEBUG 1090
SX7 X7 DEBUG 1091
NZ X7,EQ DEBUG 1092
EQ TRAP DEBUG 1093
BRGE SB2 X1-0 DEBUG 1094
SB4 X2-0 DEBUG 1095
GE B2,B4,EQ DEBUG 1096
EQ TRAP DEBUG 1097
BRLT SB2 X1-0 DEBUG 1098
SB4 X2-0 DEBUG 1099
LT B2,B4,EQ DEBUG 1100
EQ TRAP DEBUG 1101
LXJK SX2 B6 DEBUG 1102
LX2 3 DEBUG 1103
SB5 B5+X2 DEBUG 1104
LX7 X1,B5 DEBUG 1105
SA7 A1 DEBUG 1106
EQ TRAP DEBUG 1107
AXJK SX2 B6 DEBUG 1108
LX2 3 DEBUG 1109
SB5 B5+X2 DEBUG 1110
AX7 X1,B5 DEBUG 1111
SA7 A1 DEBUG 1112
EQ TRAP DEBUG 1113
MXJK SX2 B6 DEBUG 1114
LX2 3 DEBUG 1115
SB5 B5+X2 DEBUG 1116
SB4 B5-B1 DEBUG 1117
SX7 B0 DEBUG 1118
NG B4,MXST DEBUG 1119
MX7 1 DEBUG 1120
AX7 X7,B4 DEBUG 1121
MXST SA7 X3+B7 DEBUG 1122
EQ TRAP DEBUG 1123
PS SA1 =10HPROGRAM DEBUG 1124
SA2 =10HSTOP DEBUG 1125
ABORTT BX6 X1 DEBUG 1126
LX7 X2 DEBUG 1127
SA6 LINE+1 DEBUG 1128
SA7 LINE+2 DEBUG 1129
RJ GETFET DEBUG 1130
RJ PRINTL DEBUG 1131
SA1 PR DEBUG 1132
SX6 X1+100B DEBUG 1133
SX1 X1-100B DEBUG 1134
+ PL X1,*+1 DEBUG 1135
SX1 100B DEBUG 1136
SA2 FL DEBUG 1137
IX3 X6-X2 DEBUG 1139
+ NG X3,*+1 DEBUG 1140
SX6 X2-1 DEBUG 1141
LX6 30 DEBUG 1142
BX6 X6+X1 DEBUG 1143
SA6 PCTDMP DEBUG 1144
MX4 24 DEBUG 1145
RJ SNAPPRCS DEBUG 1146
+ RJ SNAP DEBUG 1147
- VFD 6/2,24/0 DEBUG 1148
VFD 30/77B,30/0 DEBUG 1149
PCTDMP DATA 0 DEBUG 1150
EQ SENDABT DEBUG 1151
TRAPX0 BX0 X6 DEBUG 1152
SA0 X7 DEBUG 1153
TRAP SA3 DETAIL DEBUG 1154
ZR X3,TLLOOP DEBUG 1155
SA3 A0+OPCODE DEBUG 1156
MX1 58 DEBUG 1157
LX3 4 DEBUG 1158
SB4 B7 DEBUG 1159
MX6 1 DEBUG 1160
SB7 B0 DEBUG 1161
TRAPX BX2 -X1*X3 DEBUG 1162
SB2 X2 DEBUG 1163
JP *+1+B2 DEBUG 1164
EQ CONTLUP DEBUG 1165
EQ AFL DEBUG 1166
EQ BFL DEBUG 1167
EQ XFL DEBUG 1168
AFL SPREAD DEBUG 1169
LX4 36 DEBUG 1170
BX6 X6+X4 DEBUG 1171
LX4 8 DEBUG 1172
BX6 X6+X4 DEBUG 1173
EQ CONTLUP DEBUG 1174
BFL SPREAD DEBUG 1175
LX4 52 DEBUG 1176
BX6 X6+X4 DEBUG 1177
EQ CONTLUP DEBUG 1178
XFL SPREAD DEBUG 1179
LX4 36 DEBUG 1180
BX6 X6+X4 DEBUG 1181
CONTLUP LX3 2 DEBUG 1182
SB7 B7+B1 DEBUG 1183
JP *+B7 DEBUG 1184
SB4 B6 DEBUG 1185
EQ TRAPX DEBUG 1186
SB4 B5 DEBUG 1187
EQ TRAPX DEBUG 1188
MX4 1 DEBUG 1189
BX4 -X4*X6 DEBUG 1190
BX6 X0 DEBUG 1191
SA6 CURRENTI DEBUG 1192
BX7 X5 DEBUG 1193
SX6 B3 DEBUG 1194
SA7 RNICON DEBUG 1195
SA6 PARCOUNT DEBUG 1196
SA3 JPCHAR DEBUG 1197
SA1 =10H DEBUG 1198
LX3 48 DEBUG 1199
IX6 X1-X3 DEBUG 1200
SA1 WR1 DEBUG 1201
SX7 B0 DEBUG 1202
SA7 A1 DEBUG 1203
SA7 NUMBLK DEBUG 1204
ZR X1,STO2 DEBUG 1205
OCTBCD X1 DEBUG 1206
MX1 24 DEBUG 1207
BX6 -X1*X7 DEBUG 1208
SA1 =4L L= DEBUG 1209
BX6 X6+X1 DEBUG 1210
IX6 X6-X3 DEBUG 1211
STO2 SA6 LINE DEBUG 1212
SA1 IFIELD DEBUG 1213
SA2 JFIELD DEBUG 1214
SX3 A0-8 DEBUG 1215
NG X3,SPCLOP DEBUG 1216
SX3 A0-20B DEBUG 1217
PL X3,NOTB DEBUG 1218
SX3 A0-14B DEBUG 1219
NG X3,NOTB DEBUG 1220
SX6 X2 DEBUG 1221
SA2 KFIELD DEBUG 1222
SA6 A2 DEBUG 1223
NOTB LX1 42-6 DEBUG 1224
LX2 18-6 DEBUG 1225
PRCSKFL1 SA3 A0+OPSKEL DEBUG 1226
IX6 X1+X3 DEBUG 1227
IX6 X2+X6 DEBUG 1228
PRCSKFL2 SA6 LINE+1 DEBUG 1229
SA1 KFIELD DEBUG 1230
SA2 OPCODE+A0 DEBUG 1231
SA3 =10H0 DEBUG 1232
SX5 X1 DEBUG 1233
LX5 54 DEBUG 1234
IX6 X3+X5 DEBUG 1235
PL X2,STO3 DEBUG 1236
OCTBCD X1 DEBUG 1237
LX7 24 DEBUG 1238
SA1 =4R DEBUG 1239
MX6 36 DEBUG 1240
BX6 X6*X7 DEBUG 1241
BX6 X6+X1 DEBUG 1242
STO3 SA6 LINE+2 DEBUG 1243
RJ GETFET DEBUG 1244
SA1 RTNIC DEBUG 1245
BX6 X1 DEBUG 1246
SA6 SNAPQ DEBUG 1247
SB3 B0 DEBUG 1248
SB4 2 DEBUG 1249
EQ SNAPL DEBUG 1250
RTNIC EQ *+1 DEBUG 1251
SA1 PARCOUNT DEBUG 1252
SA2 CURRENTI DEBUG 1253
SA5 RNICON DEBUG 1254
BX0 X2 DEBUG 1255
SB3 X1 DEBUG 1256
EQ TLLOOP DEBUG 1257
SPCLOP SX3 X3+4 DEBUG 1258
NG X3,NOTBJUMP DEBUG 1259
LX1 30-6 DEBUG 1260
LX2 12-6 DEBUG 1261
EQ PRCSKFL1 DEBUG 1262
NOTBJUMP SX3 X3+1 DEBUG 1263
NG X3,NOTXREG DEBUG 1264
SA3 JPSKEL+X1 DEBUG 1265
LX2 12-6 DEBUG 1266
IX6 X2+X3 DEBUG 1267
EQ PRCSKFL2 DEBUG 1268
NOTXREG SX3 X3+1 DEBUG 1269
NG X3,NOTJP DEBUG 1270
LX1 12-6 DEBUG 1271
SX2 B0 DEBUG 1272
EQ PRCSKFL1 DEBUG 1273
NOTJP SX3 A0 DEBUG 1274
ZR X3,PRCSKFL1 DEBUG 1275
LX2 18-6 DEBUG 1276
SA3 RJSEQ+X1 DEBUG 1277
IX6 X3+X2 DEBUG 1278
EQ PRCSKFL2 DEBUG 1279
TITLE TRACE SUBROUTINES DEBUG 1280
RNI DATA 0 DEBUG 1281
SA1 PR DEBUG 1282
SX7 X1+1 DEBUG 1283
SA7 A1 DEBUG 1284
RJ CKFL DEBUG 1285
SA5 X7 DEBUG 1286
SA7 =SWR2 DEBUG 1287
EQ RNI DEBUG 1288
GETPARCL DATA 0 DEBUG 1289
SX1 B3-60 DEBUG 1290
NZ X1,GO1 DEBUG 1291
BX0 X5 GET PREVIOUS WORD DEBUG 1292
SB3 B0 DEBUG 1293
SA1 =SWR2 DEBUG 1294
SX7 X1 DEBUG 1295
SA7 =SWR1 DEBUG 1296
GO1 SX1 B3-15 DEBUG 1297
NZ X1,GO2 DEBUG 1298
RJ RNI DEBUG 1299
GO2 LX4 X0,B3 DEBUG 1300
LX4 15 DEBUG 1301
MX1 45 DEBUG 1302
BX4 -X1*X4 DEBUG 1303
SB3 B3+15 DEBUG 1304
EQ GETPARCL DEBUG 1305
CKFL DATA 0 DEBUG 1306
SA1 FL DEBUG 1307
NZ X1,CKX DEBUG 1308
GETFL SA1 1 DEBUG 1309
NZ X1,* DEBUG 1310
SX6 B0 DEBUG 1311
SA6 FL DEBUG 1312
SA1 REQFL DEBUG 1313
SX6 A6 ******* 1
LX6 18 ******* 2
BX6 X1+X6 ******* 3
SA6 B1 DEBUG 1315
+ SA1 1 DEBUG 1316
NZ X1,* DEBUG 1317
SA1 FL DEBUG 1318
CKX SX7 X7 ******* 4
IX1 X7-X1 DEBUG 1322
NG X1,CKFLB SNESE NO ARITH ERROR DEBUG 1323
ARITHERR SA1 FL+1 DEBUG 1324
SX6 B1 DEBUG 1325
SA6 A1 DEBUG 1326
ZR X1,GETFL DEBUG 1327
SA1 =10HARITH ERRO DEBUG 1328
SA2 =10HR MODE 1. DEBUG 1329
EQ ABORTT DEBUG 1330
CKFLB SA1 CMREFFST DEBUG 1331
SA1 X1 DEBUG 1332
SX6 B0 DEBUG 1333
SA6 FL+1 DEBUG 1334
CKFLL ZR X1,CKFL DEBUG 1335
BX1 X1-X7 DEBUG 1336
SX1 X1 DEBUG 1337
ZR X1,CMSTOP DEBUG 1338
SA1 A1+1 DEBUG 1339
EQ CKFLL DEBUG 1340
CMSTOP SA7 TEMPT DEBUG 1341
SA2 =10H0MEMORY DEBUG 1342
SA3 =10HREFERENCE DEBUG 1343
BX6 X2 DEBUG 1344
LX7 X3 DEBUG 1345
SA3 =10HSNAPSHOT DEBUG 1346
SA6 LINE DEBUG 1347
SA7 LINE+1 DEBUG 1348
BX6 X3 DEBUG 1349
SA6 A7+B1 DEBUG 1350
SA4 A1 DEBUG 1351
LX4 6 DEBUG 1352
RJ SAVE DEBUG 1353
RJ GETFET DEBUG 1354
RJ PRINTL DEBUG 1355
RJ SNAPPRCS DEBUG 1356
SA1 TEMPT DEBUG 1357
OCTBCD X1 DEBUG 1358
SA7 =SBCDADDR DEBUG 1359
SA1 TEMPT DEBUG 1360
SA1 X1 DEBUG 1361
OCTBCD X1 DEBUG 1362
SA1 =10HADDRESS = DEBUG 1363
SA4 =10H CONTENTS DEBUG 1364
SA2 BCDADDR DEBUG 1365
MX0 24 DEBUG 1366
BX2 -X0*X2 DEBUG 1367
SA3 =4L DEBUG 1368
SA6 LINE+4 DEBUG 1369
SA7 LINE+5 DEBUG 1370
BX6 X3+X2 DEBUG 1371
LX7 X1 DEBUG 1372
SA6 LINE+2 DEBUG 1373
SA7 LINE+1 DEBUG 1374
BX6 X4 DEBUG 1375
SA6 LINE+3 DEBUG 1376
RJ PRINTL DEBUG 1377
RJ RENTER DEBUG 1378
SA3 TEMPT DEBUG 1379
SX7 X3 DEBUG 1380
EQ CKFL DEBUG 1381
SAVE BSSZ 1 DEBUG 1382
BX6 X0 DEBUG 1383
SA6 CURRENTI DEBUG 1384
BX7 X5 DEBUG 1385
SA7 RNICON DEBUG 1386
SX6 B3 DEBUG 1387
SA6 PARCOUNT DEBUG 1388
SX7 B5 DEBUG 1389
SX6 B6 DEBUG 1390
SA7 OP1 DEBUG 1391
SA6 OP2 DEBUG 1392
SX7 B7 DEBUG 1393
SX6 A0 DEBUG 1394
SA7 OP3 DEBUG 1395
SA6 OPCDE DEBUG 1396
BX7 X1 DEBUG 1397
BX6 X2 DEBUG 1398
SA7 OPR1 DEBUG 1399
SA6 OPR2 DEBUG 1400
EQ SAVE DEBUG 1401
SNAPPRCS DATA 0 DEBUG 1402
MX1 24 DEBUG 1403
BX4 X1*X4 DEBUG 1404
SX7 B0 DEBUG 1405
SA7 NUMBLK DEBUG 1406
RJ GETFET DEBUG 1407
SA1 RTNI DEBUG 1408
BX6 X1 DEBUG 1409
SA6 SNAPQ DEBUG 1410
SB3 B0 DEBUG 1411
SB4 B0 DEBUG 1412
NZ X4,SNAPL DEBUG 1413
RTNADR EQ SNAPPRCS DEBUG 1414
RENTER DATA 0 DEBUG 1415
SA1 OPCDE DEBUG 1416
SA2 OP1 DEBUG 1417
SA3 OP2 DEBUG 1418
SA4 OP3 DEBUG 1419
SA5 RNICON DEBUG 1420
SA0 X1 DEBUG 1421
SB5 X2 DEBUG 1422
SB6 X3 DEBUG 1423
SB7 X4 DEBUG 1424
SA1 PARCOUNT DEBUG 1425
SA3 CURRENTI DEBUG 1426
SA4 NXTPAR DEBUG 1427
SB3 X1 DEBUG 1428
BX0 X3 DEBUG 1429
SA1 OPR1 DEBUG 1430
SA2 OPR2 DEBUG 1431
EQ RENTER DEBUG 1432
RTNI EQ RTNADR DEBUG 1433
REGI RJ RESTORE DEBUG 1434
SNAPCALL RJ SAVE DEBUG 1435
RJ GETFET DEBUG 1436
SA1 RTNIB DEBUG 1437
BX6 X1 DEBUG 1438
SB2 B1 DEBUG 1439
SA6 SNAPQ DEBUG 1440
EQ SNAPY DEBUG 1441
RTNIB EQ *+1 DEBUG 1442
SA1 REGI DEBUG 1443
BX6 X1 DEBUG 1444
SA6 SNAPQ DEBUG 1445
RJ RENTER DEBUG 1446
TRCECALL BSS 0 DEBUG 1447
TRACALL SA1 PR DEBUG 1448
SX6 X1-1 DEBUG 1449
SA6 A1 DEBUG 1450
EQ ABTWORD DEBUG 1451
UNTRCALL RJ RESTORE RESTORE REGISTERS DEBUG 1452
EQ UNTRACE RETURN TO CALLING PROGRAM DEBUG 1453
CMREFC SB2 B1 DEBUG 1454
SA1 CMREF DEBUG 1455
AX1 30 DEBUG 1456
SX6 X1-1 DEBUG 1457
SA6 PR DEBUG 1458
SUB DEBUG 1459
SA1 CMREF DEBUG 1460
AX1 30 DEBUG 1461
SX6 X1 DEBUG 1462
SA6 PR DEBUG 1463
EQ ABTWORD DEBUG 1464
* DEBUG 1465
PRCSOPT SX7 B5-1 DEBUG 1466
SA7 DETAIL DEBUG 1467
JP TRAP DEBUG 1468
* DEBUG 1469
UNTRACE DATA 0 DEBUG 1470
EQ *-1 DEBUG 1471
TITLE OPCODE TABLE DEBUG 1472
* TABLE OF OPCODE FORMS DEBUG 1473
OPCODE BSS 0 DEBUG 1474
OPCODE N,N,K PS DEBUG 1475
OPCODE N,N,K RJ DEBUG 1476
OPCODE B,N,K JP DEBUG 1477
OPCODE N,X,K X REG TEST DEBUG 1478
DUP 4,1 DEBUG 1479
OPCODE B,B,K BREG TEST DEBUG 1480
OPCODE X,X,N TWO REG BOOL DEBUG 1481
DUP 3,1 DEBUG 1482
OPCODE X,X,X THREE REG BOOL DEBUG 1483
OPCODE X,N,X DEBUG 1484
DUP 3,1 DEBUG 1485
OPCODE X,X,X DEBUG 1486
OPCODE X,N,N LXJK DEBUG 1487
OPCODE X,N,N AXJK DEBUG 1488
DUP 6,1 DEBUG 1489
OPCODE X,B,X AX X,B DEBUG 1490
DUP 8,1 DEBUG 1491
OPCODE X,X,X ADD UNITS DEBUG 1492
DUP 3,1 DEBUG 1493
OPCODE X,X,X MULT UNIT DEBUG 1494
OPCODE X,N,N MXJK DEBUG 1495
DUP 2,1 DEBUG 1496
OPCODE X,X,X DIVIDE UNIT DEBUG 1497
OPCODE N,N,N NOP DEBUG 1498
OPCODE X,N,X CX DEBUG 1499
OPCODE A,A,K DEBUG 1500
OPCODE A,B,K DEBUG 1501
OPCODE A,X,K DEBUG 1502
OPCODE A,X,B DEBUG 1503
DUP 2,1 DEBUG 1504
OPCODE A,A,B DEBUG 1505
DUP 2,1 DEBUG 1506
OPCODE A,B,B DEBUG 1507
OPCODE B,A,K DEBUG 1508
OPCODE B,B,K DEBUG 1509
OPCODE B,X,K DEBUG 1510
OPCODE B,X,B DEBUG 1511
DUP 2,1 DEBUG 1512
OPCODE B,A,B DEBUG 1513
DUP 2,1 DEBUG 1514
OPCODE B,B,B DEBUG 1515
OPCODE X,A,K DEBUG 1516
OPCODE X,B,K DEBUG 1517
OPCODE X,X,K DEBUG 1518
OPCODE X,X,B DEBUG 1519
DUP 2,1 DEBUG 1520
OPCODE X,A,B DEBUG 1521
DUP 2,1 DEBUG 1522
OPCODE X,B,B DEBUG 1523
TITLE OPCODE SKELETON TABLES DEBUG 1524
OPSKEL DIS 1, PS DEBUG 1525
DIS 1, DEBUG 1526
DIS 1, JP B0+ DEBUG 1527
DIS 1, DEBUG 1528
DIS 1, EQ B0,B0, 04 DEBUG 1529
DIS 1, NE B0,B0, 05 DEBUG 1530
DIS 1, GE B0,B0, 06 DEBUG 1531
DIS 1, LT B0,B0, 07 DEBUG 1532
DIS 1, BX0 X0,X DEBUG 1533
DIS 1, BX0 X0*X DEBUG 1534
DIS 1, BX0 X0+X DEBUG 1535
DIS 1, BX0 X0-X DEBUG 1536
DIS 1, BX0 -X0,X DEBUG 1537
DIS 1, BX0 -X0*X 15 DEBUG 1538
DIS 1, BX0 -X0+X 16 DEBUG 1539
DIS 1, BX0 -X0-X 17 DEBUG 1540
DIS 1, LX0 0 DEBUG 1541
DIS 1, AX0 0 DEBUG 1542
DIS 1, LX0 B0,X 22 DEBUG 1543
DIS 1, AX0 B0,X DEBUG 1544
DIS 1, NX0 B0,X DEBUG 1545
DIS 1, ZX0 B0,X DEBUG 1546
DIS 1, UX0 B0,X DEBUG 1547
DIS 1, PX0 B0,X DEBUG 1548
DIS 1, FX0 X0+X DEBUG 1549
DIS 1, FX0 X0-X DEBUG 1550
DIS 1, DX0 X0+X DEBUG 1551
DIS 1, DX0 X0-X DEBUG 1552
DIS 1, RX0 X0+X DEBUG 1553
DIS 1, RX0 X0-X DEBUG 1554
DIS 1, IX0 X0+X DEBUG 1555
DIS 1, IX0 X0-X DEBUG 1556
DIS 1, FX0 X0*X DEBUG 1557
DIS 1, RX0 X0*X DEBUG 1558
DIS 1, DX0 X0*X DEBUG 1559
DIS 1, MX0 0 DEBUG 1560
DIS 1, FX0 X0/X DEBUG 1561
DIS 1, RX0 X0/X DEBUG 1562
DIS 1, NO DEBUG 1563
DIS 1, CX0 X DEBUG 1564
DIS 1, SA0 A0+ DEBUG 1565
DIS 1, SA0 B0+ DEBUG 1566
DIS 1, SA0 X0+ DEBUG 1567
DIS 1, SA0 X0+B DEBUG 1568
DIS 1, SA0 A0+B 54 DEBUG 1569
DIS 1, SA0 A0-B DEBUG 1570
DIS 1, SA0 B0+B 56 DEBUG 1571
DIS 1, SA0 B0-B DEBUG 1572
DIS 1, SB0 A0+ 60 DEBUG 1573
DIS 1, SB0 B0+ 61 DEBUG 1574
DIS 1, SB0 X0+ DEBUG 1575
DIS 1, SB0 X0+B DEBUG 1576
DIS 1, SB0 A0+B 64 DEBUG 1577
DIS 1, SB0 A0-B DEBUG 1578
DIS 1, SB0 B0+B DEBUG 1579
DIS 1, SB0 B0-B DEBUG 1580
DIS 1, SX0 A0+ 70 DEBUG 1581
DIS 1, SX0 B0+ 71 DEBUG 1582
DIS 1, SX0 X0+ DEBUG 1583
DIS 1, SX0 X0+B DEBUG 1584
DIS 1, SX0 A0+B DEBUG 1585
DIS 1, SX0 A0-B DEBUG 1586
DIS 1, SX0 B0+B DEBUG 1587
DIS 1, SX0 B0-B DEBUG 1588
JPSKEL DIS 1, ZR X0, DEBUG 1589
DIS 1, NZ X0, DEBUG 1590
DIS 1, PL X0, DEBUG 1591
DIS 1, NG X0, DEBUG 1592
DIS 1, IR X0, DEBUG 1593
DIS 1, OR X0, DEBUG 1594
DIS 1, DF X0, DEBUG 1595
DIS 1, ID X0, DEBUG 1596
RJSEQ DIS 1, RJ DEBUG 1597
DIS 1, RE B0+ DEBUG 1598
DIS 1, WE B0+ DEBUG 1599
DIS 1, CEJ B0+ DEBUG 1600
TITLE TEMPORARIES DEBUG 1601
CMREFFST VFD 60/BFR DEBUG 1602
CMREFIN VFD 60/BFR DEBUG 1603
CMREFLMT VFD 60/BFR+10 DEBUG 1604
BFR BSSZ 10 DEBUG 1605
ECSFL DATA 0 DEBUG 1606
ECSCALL VFD 18/3RMEM,2/1,22/1,18/ECSFL DEBUG 1607
FL DATA 0 DEBUG 1608
DATA 0 DEBUG 1609
REQFL DATA 0LRFLP ******* 5
DETAIL BSSZ 1 DEBUG 1611
TEMPT BSSZ 1 DEBUG 1612
CURRENTI BSSZ 1 DEBUG 1613
RNICON BSSZ 1 DEBUG 1614
PARCOUNT BSSZ 1 DEBUG 1615
OP1 BSSZ 1 DEBUG 1616
OP2 BSSZ 1 DEBUG 1617
OP3 BSSZ 1 DEBUG 1618
OPCDE BSSZ 1 DEBUG 1619
CMREF. EQU CMREF DEBUG 1620
ENTRY CMREF. DEBUG 1621
OPR1 BSSZ 1 DEBUG 1622
OPR2 BSSZ 1 DEBUG 1623
NXTPAR BSSZ 1 DEBUG 1624
SNAPONLY ENDIF DEBUG 1625
TRACE. EQU TRACE DEBUG 1626
SNAP. EQU SNAP DEBUG 1627
UTRACE. EQU UNTRACE DEBUG 1628
DBFILE. EQU FILENAM DEBUG 1629
ENTRY TRACE.,SNAP.,DBFILE.,UTRACE. DEBUG 1630
END DEBUG 1631