ERROR
IDENT ERROR ERROR 1
TITLE RUN-TIME ERROR PROCESSING ERROR 2
* FOR A LISTING OF THE SNODEF COMDECK, CALLED BELOW, SEE MAINLUP. ERROR 3
LIST -L ERROR 4
*CALL,SNODEF ERROR 5
LIST L ERROR 6
* ERROR 7
* ERROR ERROR 8
ENTRY ADDS1,SUBTRS,DIVS,MULTS,EXP ERROR 9
ENTRY FATBUMP ERROR 10
ENTRY RTERROR,FILEWD,SJCALL ERROR 11
ENTRY MSGOUT ERROR 12
* UTILITY ERROR 13
EXT ICX1X6 ERROR 14
* IO ERROR 15
EXT ABT,PUTWD ERROR 16
* ERROR 17
TITLE ERROR CALLS ERROR 18
ERR32 ERROR 32 ERROR 19
ADDS1 EQU ERR32 ERROR 20
SUBTRS EQU ERR32 ERROR 21
MULTS EQU ERR32 ERROR 22
DIVS EQU ERR32 ERROR 23
EXP EQU ERR32 ERROR 24
* ERROR 25
NOEND ERROR 0 ERROR 26
ERR2 ERROR 2 ERROR 27
ERR3 ERROR 3 ERROR 28
ERR4 ERROR 4 ERROR 29
ERR6 ERROR 6 ERROR 30
ERR7 ERROR 7 ERROR 31
ERR9 ERROR 9 ERROR 32
ERR13 ERROR 13 ERROR 33
ERR14 ERROR 14 ERROR 34
ERR17 ERROR -17 ERROR 35
ERR19 ERROR 19 ERROR 36
ERR21 ERROR 21 ERROR 37
ERR24 ERROR 24 ERROR 38
ERR27 ERROR 27 ERROR 39
ERR28 ERROR 28 ERROR 40
ERR29 ERROR 29 ERROR 41
ERR30 ERROR 30 ERROR 42
ERR31 ERROR 31 ERROR 43
ERR35 ERROR 35 ERROR 44
ERR37 ERROR 37 ERROR 45
ERR38 ERROR 38 ERROR 46
ERR39 ERROR 39 ERROR 47
ERR40 ERROR 40 ERROR 48
ERR42 ERROR 42 ERROR 49
ERR44 ERROR 44 ERROR 50
ERR48 ERROR 48 ERROR 51
ERR49 ERROR 49 ERROR 52
ERR50 ERROR 50 ERROR 53
ERR52 ERROR 52 ERROR 54
ERR53 ERROR 53 ERROR 55
ERR55 ERROR 55 ERROR 56
ERR56 ERROR 56 ERROR 57
ERR57 ERROR 57 ERROR 58
ERR59 ERROR 59 ERROR 59
* ERROR 60
FATBUMP STREAM OUTSTRM . OUT OF SPACE DURING COMPILATION ERROR 61
BX6 X6-X6 ERROR 62
RJ PUTWD . GUARANTEE ZERO BYTE FOR LAST LINE ERROR 63
ERROR -54 ERROR 64
TITLE RUN-TIME ERROR MESSAGE PRINTOUT ERROR 65
* SB5 ERROR.NUMBER . THIS IS THE CALLING SEQUENCE ERROR 66
* JP RTERROR . GENERATED BY THE @ERROR@ MACRO ERROR 67
* ERROR 68
* WE PRINT AN ERROR TERMINATION MESSAGE, INCLUDING STATEMENT NUMBER, ERROR 69
* FUNCTION CALL LEVEL, AND A DIAGNOSTIC. THIS INFORMATION GOES TO THE ERROR 70
* STANDARD OUTPUT FILE AND TO THE DAYFILE. THE DIAGNOSTIC TEXTS ARE INERROR 71
* AN OVERLAY, PRECEDED BY AN INDEX OF MESSAGE POINTERS PACKED TWO/WORD.ERROR 72
* THIS OVERLAY IS LOADED ON TOP OF UNNEEDED SNOBOL SYSTEM CODE. ERROR 73
* ERROR 74
RTERROR SA1 LCALL . RA+1 REQUEST WORD FOR THE LOADER ERROR 75
BX6 X1 ERROR 76
BX7 X7-X7 . WHEN LOADING IS COMPLETE, CELL 67B ERROR 77
SA7 67B . WILL BE SET NONZERO ERROR 78
SA6 1 . ISSUE REQUEST ERROR 79
RTERRL1 SA1 1 . AND WAIT FOR ERROR 80
NZ X1,RTERRL1 . MONITOR TO SEE IT ERROR 81
RTERRL2 RCL . USE PERIODIC RECALL ERROR 82
SA1 67B . TO BLOCK UNTIL ERROR 83
ZR X1,RTERRL2 . THE OVERLAY IS LOADED ERROR 84
* ERROR 85
STREAM OUTSTRM . SET B2 = OUTPUT FILE BLOCK ERROR 86
* ERROR 87
SA1 TERMMSG . =10H1ERROR TER ERROR 88
SA4 A1+1 . =8LMINATION ERROR 89
BX6 X1 ERROR 90
SX5 61B . =(1R1 EXOR 1R ) ERROR 91
LX5 60-6 ERROR 92
BX7 X1-X5 . REMOVE EJECT CARRIAGE CONTROL CHAR ERROR 93
SA7 A1 . FOR THE DAYFILE VERSION ERROR 94
RJ PUTWD ERROR 95
BX6 X4 ERROR 96
RJ PUTWD ERROR 97
SX6 TERMMSG ERROR 98
CALL MSGOUT ERROR 99
* ERROR 100
* IF B5<0, THE SNOBOL SYSTEM IS IN A BAD STATE; STATEMENT NUMBER AND ERROR 101
* LEVEL ARE NOT PRINTED. ERROR 102
* ERROR 103
NG B5,RTERRPD . GO PRINT DIAGNOSTIC ERROR 104
SX1 1 . INITIALIZE STATEMENT NUMBER = 1 ERROR 105
SB1 A5 . MICOP POINTER ERROR 106
SA2 CODLIST . HEAD OF LIST OF CODE BLOCKS ERROR 107
NEXTBLOK SA3 X2 . FETCH NEXT CODE BLOCK HEADER ERROR 108
SB3 X2 ERROR 109
SX2 X3 . F1 IS LINK ERROR 110
AX3 18 . F2 IS BYPASS ERROR 111
SB4 X3-1 ERROR 112
SB4 B3+B4 . INITIALIZE B4 = ADDR. OF FIRST MIC.ERROR 113
NEXTMICW EQ B1,B4,FOUNDRUL . FOUND CURRENT POSITION ERROR 114
SA3 B4+0 ERROR 115
PL X3,CKENDBLK . NOT END OF RULE ERROR 116
SX1 X1+1 . INCREMENT STATEMENT NUMBER ERROR 117
CKENDBLK SB4 B4-1 ERROR 118
GT B4,B3,NEXTMICW . MORE MICOPS, THIS BLOCK ERROR 119
NZ X2,NEXTBLOK . MORE BLOCKS ERROR 120
JP 400000B+* . SYSTEM ERROR, A5 OUT OF RANGE ERROR 121
* ERROR 122
FOUNDRUL BX5 X5-X5 . INITIALIZE FNCLEVEL = 0 ERROR 123
SA2 B6 . THIS LOOP ERROR 124
ZR X2,FOUNDBOT . IS LIKE THE ERROR 125
CKCALL PL X2,NEXTSTKE . ONE USED ERROR 126
SX5 X5+1 . BY STANDARD ERROR 127
NEXTSTKE SB1 X2 . PROCEDURE FNCLEVEL() ERROR 128
SA2 A2-B1 . IN THE ASSEMBLY ERROR 129
NZ X2,CKCALL . PROCS ERROR 130
* ERROR 131
FOUNDBOT RJ ICX1X6 . BINARY IN X1 => STRING IN X6 ERROR 132
SA1 STNOMSG . =10H IN STATEM ERROR 133
SA4 A1+1 . =4LENT ERROR 134
LX6 60-4*6 . RIGHT SHIFT 4 CHARACTER POSITIONS ERROR 135
BX4 X4+X6 ERROR 136
BX7 X4 ERROR 137
BX6 X1 ERROR 138
SA7 A4 ERROR 139
RJ PUTWD . (SAVES X4,X5) ERROR 140
BX6 X4 ERROR 141
RJ PUTWD ERROR 142
SX6 STNOMSG ERROR 143
CALL MSGOUT ERROR 144
BX1 X5 . FNCLEVEL ERROR 145
RJ ICX1X6 ERROR 146
SA1 FNCLMSG . =10H AT LEVEL ERROR 147
SA6 A1+1 ERROR 148
BX4 X6 ERROR 149
BX6 X1 ERROR 150
RJ PUTWD ERROR 151
BX6 X4 ERROR 152
RJ PUTWD ERROR 153
SB5 -B5 . HERE TWO WRONGS MAKE A RIGHT ERROR 154
SX6 FNCLMSG ERROR 155
CALL MSGOUT ERROR 156
* ERROR 157
ERROR 158
RTERRPD SX1 -B5 . -(-ERROR.NUMBER) ERROR 159
LX1 60-1 . RIGHT CYCLE X1 BY 1 BIT ERROR 160
SA4 RTEDIR+X1 ERROR 161
BX6 X6-X6 ERROR 162
NG X1,RTERRINI . EVEN ERROR NUMBERS OCCUPY ERROR 163
LX4 30 . UPPER HALVES OF DIRECTORY WORDS ERROR 164
RTERRINI SX4 RTEDIR+X4 . ABSOLUTE TEXT POINTER ERROR 165
SB1 X4 . COPY IT ERROR 166
MX5 60-12 . COMPLEMENT OF A 1-BYTE MASK ERROR 167
RJ PUTWD . OUTPUT A BLANK LINE ERROR 168
* ERROR 169
RTERRLUP SA1 B1 . PRINT OUT ERROR 170
SB1 B1+1 . THE ERROR ERROR 171
BX6 X1 . MESSAGE, WHICH ERROR 172
RJ PUTWD . ENDS WITH ERROR 173
BX2 -X5*X6 . A ERROR 174
NZ X2,RTERRLUP . ZERO BYTE ERROR 175
* ERROR 176
SX6 X4 . TEXT POINTER ERROR 177
CALL MSGOUT,,ABT . SEND MESSAGE TO DAYFILE AND ABORT ERROR 178
* ERROR 179
* ERROR 180
LCALL VFD 18/3LLDR,42/SJCALL ERROR 181
* ERROR 182
SJCALL VFD 42/0LSNOJOB,18/0 ******* 1
VFD 6/1,6/0,5/0,1/1,1/1,41/RTEDIR-1 ERROR 184
VFD 60/0 ERROR 185
* ERROR 186
FILEWD VFD 6/1,6/0,6/0,1/1,41/RTEDIR-1 ERROR 187
* ERROR 188
* ERROR 189
TERMMSG DATA 10H1ERROR TER ERROR 190
DATA 8LMINATION ERROR 191
* ERROR 192
STNOMSG DATA 10H IN STATEM ERROR 193
DATA 4LENT ERROR 194
* ERROR 195
FNCLMSG DATA 10H AT LEVEL ERROR 196
DATA 0 ERROR 197
* ERROR 198
* ERROR 199
* MSGOUT ERROR 200
* ERROR 201
* PARAMETERS: X6 = ADDRESS OF MESSAGE FOR THE DAYFILE ERROR 202
* B1 = RETURN ERROR 203
* ERROR 204
* USES: A1/X1, A6/X6, A7/X7 ERROR 205
* ERROR 206
MSGOUT SA1 MSGCALLR . RA+1 REQUEST WORD, RECALL BIT ON ERROR 207
BX7 X1+X6 ******* 2
SA7 1 . ISSUE REQUEST ERROR 211
MSGOUTL SA1 1 ERROR 212
NZ X1,MSGOUTL ERROR 213
JP B1 ERROR 214
* ERROR 215
MSGCALLR VFD 24/0LMSGP,18/0,18/0 ******* 3
* ERROR 217
* ERROR 218
BSS 1 . OVERLAY 50-TABLE WORD LANDS HERE ERROR 219
RTEDIR BSS 0 . ORIGIN FOR THE TEXTS OVERLAY ERROR 220
* ERROR 221
* ERROR 222
END ERROR 223